SPICE parameters for Germanium transistors?

Started by brett, September 07, 2009, 12:54:53 AM

Previous topic - Next topic

brett

Hi
Has anybody estaimated SPICE parameters for common Ge PNP devices, such as the AC128 and NKT275 ?
thanks
Brett Robinson
Let a hundred flowers bloom, let a hundred schools of thought contend. (Mao Zedong)

CynicalMan

There are a couple of germanium transistor models floating around on the internet. I've tried one or two and they just don't work like real germanium transistors. The forward voltages on the base-emitter and base-collector junctions are way too high and the transistors won't work in many circuits. That being said, here's a thread on an audio forum where someone claims to have found one: http://www.diyaudio.com/forums/showthread.php?threadid=117257

edvard

#2
I saw that one too, and it's good to see someone who knows their smoke pointed out the errors right away.
I found an AC128 model from a college paper on the Fuzz Face:
.model AC128 PNP(Bf=70 Vje=0.2 Is=1.41f Xti=3 Eg=1.11
+ Ne=1.5 Ise=0 Ikf=80m Xtb=1.5 Br=4.977 Nc=2
+ Isc=0 Ikr=0 Rc=2.5 Cjc=9.728p Mjc=0.5776
+ Vjc=0.2 Fc=0.5 Cje=8.063p Mje=0.3677 Tr=33.42n
+ Tf=179.3p Itf=0.4 Vtf=4 Xtf=6 Rb=10)


Can anybody verify this one?
The gain is more or less controlled by the 'Bf' parameter.

I also found a 2N344 model:
.model 2N344 PNP(Is=1e-10 bf=11 Vaf=15 Cje=5p Cjc=2.5p Tf=3n
+ Eg=.67 Rb=100 Re=10)


If you're good with the math and can find a decent datasheet, maybe try rolling your own:
http://www.analogservices.com/excel.htm
All children left unattended will be given a mocha and a puppy

CynicalMan

Quote from: edvard on September 07, 2009, 12:50:53 PM
If you're good with the math and can find a decent datasheet, maybe try rolling your own:
http://www.analogservices.com/excel.htm

I haven't used that before but there are two problems you might run up against. First, that might be geared towards silicon transistors and it might be bad for germanium. Second, it's difficult to find good values for germanium devices because of their huge variability.

I'll check out that model and see what I get.

brett

Hi
thanks for the replies.  I thought I hadn't searched the internet sufficiently, but it really does seem that these data are hard to get.

Quoteit's difficult to find good values for germanium devices because of their huge variability
To overcome this, I was thinking of building a dozen different models (low/mid/high hFE x  mid/high B-C capacitance x low/high leakage ??).  I am interested in "covering" the classic AC, OC and NKT devices (variable hFE, hugely variable leakage), GT (Russian) devices (consistent hFE, medium to low leakage), and 2SC (Japanese) devices (consistent hFE, low leakage). 

Quote.model AC128 PNP(Bf=70 Vje=0.2 Is=1.41f Xti=3 Eg=1.11
+ Ne=1.5 Ise=0 Ikf=80m Xtb=1.5 Br=4.977 Nc=2
+ Isc=0 Ikr=0 Rc=2.5 Cjc=9.728p Mjc=0.5776
+ Vjc=0.2 Fc=0.5 Cje=8.063p Mje=0.3677 Tr=33.42n
+ Tf=179.3p Itf=0.4 Vtf=4 Xtf=6 Rb=10)

This is a great start for me.  The parameters that I feel are a bit dodgy include Br (reverse hFE=4.977), which my experience tells me is often as much as half of the forward hFE (Bf=70).  So I'd nudge Br up to at least 10 (maybe 20 or 30 ?). Cjc (B-C capacitance) seems low at 9.728 pF (and why are there 3 decimal places doing there on a parameter that probably varies by several pF).  Would 50pF be more in the ballpark?  (Gus once told us that early Ge audio transistors had high capacitance and low Ft)  Also, Vje and Vjc (the forward voltage drop on the junctions) are a bit too low at 0.2 V.  We usually assume that the voltage drop for Germanium is 0.3 V.  Because this can be an important parameter, this might be one where some accuracy would help.  I'd use at least 0.26 V and less than 0.3 V (so 0.28 V seems logical).

I'm not familiar with several parameters, so it will take me a while to research them and get back with some models.  In the meantime, any help or feedback will be greatly appreciated.
cheers
Brett Robinson
Let a hundred flowers bloom, let a hundred schools of thought contend. (Mao Zedong)

brett

Hi
I've been doing some research and simulations.

I've got a basic PNP Germanium device model here.  Although I've called it AC128, it is generic.
Feel free to "roll your own".

.model AC128-hFE50 PNP(Bf=50 Br=5
+ ; Forward and reverse Beta.  Set as appropriate.
+ ; 40 to 80 is typical of many early audio devices. 
+ ; 80 to 200 for later high quality devices. (esp Japanese and Soviet devices)
+ Is=1f
+ ; forward saturation current
+ Ikf=20m
+ ; Beta falls off above 20 mA (Ikf=current at upper "knee" in Beta)
+ ; assumes a low current early Germanium device such as an AC128
+ ; set to higher value for higher current devices
+ Xti=3.5 Xtb=2.0
+ ; temperature coefficients for effects on Is (Xti) and Beta (Xtb). 
+ ; Both coefficients are set larger than for Si devices (where typically Xti=3 and Xtb=1.5)
+ ; !these are guesses
+ VAF=60 
+ ; Ge devices have low early voltage (VAF=60 V rather than 100 or 1000 V)
+ ; data for VAF from Ic vs VBE curves for an AC128, taking average of Ib=200uA (VAF=40) and Ib=400uA (VAF=80)
+ Nc=3 Ne=2.5 Br=5
+ ; increased Ne and Nc (ideal diodes have N=1, very poor ones have N >>1)
+ ; Nc is usually larger than Ne
+ ; !these are guesses
+ Isc=1u
+ ; Leakage current (Isc) is much higher for Ge than for Si.
+ ; This value gives 60uA at 9V in the circuit decribes in "Technology of the Fuzzface" at geofex.com
+ ; Adjust according to the particular device (e.g. 5u for a leaky AC128s, OCs, 0.02u for quality Soviet GTs, Japanese 2SBs)
+ ; Si leakage for cheap small signal devices may be ise=20p isc=10p (data for a 2N2222A)
+ Eg=1.11 Vjc=0.28 Vje=0.28
+ ; Energy gap for temperature effect on IS is 1.11 (check if wanting to simulate temperature effects)
+ ; and junction voltage in Germanium devices is approx 0.28 V.  Same as forward diode voltage.
+ Rc=10 Rb=50 Re=1
+ ; Collector, base and emitter resistances are all higher than for Si (typically 2, 20 and 0.1, respectively)
+ Cjc=50p Cje=10p
+ ; high junction capacitances due to basic manufacturing processes.  Much lower for RF devices.
+ ; educated guesses
+ Mjc=0.4 Mje=0.4
+ ; same expontential factors as for Si devices
+ ; educated guess that they are similar.  Might be wrong.
+ Tf=1u Tr=20u Itf=0.4 Vtf=4 Xtf=6)
+ ; Tf is the forward transit time (seconds).
+ ; It is set for Ft=1 MHz. Tr= approx 20xTf (Tf limits high frequency gain at high collector current)
+ ; Junction capacitances (Cjc and Cje, together with Mjc and Mje) limit high frequency gain at low collector current
+ ; These data are educated guesses


It seems to work ok in some very basic simulations where I've tested it for leakage, and gain at high and low bias currents.  For "normal" conditions (e.g. simulating RG's transistor tester), theis model gives 60 uA of leakage and gain in the high 40s.  I haven't done any frequency/bandwidth testing yet.  Some data that I've seen suggests that some Ge devices have low gain at high frequencies, especially at low Ic (e.g. one graph of an AC128 with Ft at 1 MHz around Ic=10 mA, but Ft is about 100 kHz ( :icon_eek: ) at 0.1 mA).

However, there's a strange behaviour in the model above that I can't work out: when I use very low bias currents (like for Q1 of the Fuzzface), the gain can be greater than Bf (which I thought was the maximum Beta ??).  My test simulation is simple: -9.0 V DC supply (0=gnd) , a 100k collector resistor, a 2.2M bias resistor (collector to base), and emitter to ground.  The AC output is 120 mV p-p for a 1 mV p-p input (gain of 120, when Bf=50).  Huh?  How can the gain be higher than Bf?

Any feedback is much appreciated.

Brett Robinson
Let a hundred flowers bloom, let a hundred schools of thought contend. (Mao Zedong)

PRR

#6
> I'm not familiar with several parameters

http://www.diodes.com/zetex/?ztx=3.0/3-10#bipolar
QuoteIS and NF control Icbo and the value of Ic at medium bias levels.
ISE and NE control the fall in hFE that occurs at low Ic.
BF controls peak forward hFE and XTB controls how it varies with temperature.
BR controls peak reverse hFE i.e. collector and emitter reversed.
IKF and NK control the current and the rate at which hFE falls at high collector currents.
IKR controls where reverse hFE falls at high emitter currents.
ISC and NC controls the fall of reverse hFE at low currents.
RC, RB and RE add series resistance to these device terminals.
VAF controls the variation of collector current with voltage when the transistor is operated in its linear region.
VAR is the reverse version of VAF.
CJC, VJC and MJC control Ccb and how it varies with Vcb.
CJE, VJE and MJE control Cbe Ccb and how it varies with Veb.
TF controls Ft and switching speeds.
TR controls switching storage times.
RCO, GAMMA, QUASIMOD control the quasi-saturation region.


Reverse beta is mostly meaningless, even in highly over-driven amplifiers. (It comes up in choppers, also in one of R.G.'s clever power switches.)

> Ge devices have low early voltage

Some later ones were quite high; OTOH going way back VAF could be close to 20V. 60V is probably a reasonable ballpark.

> Leakage current (Isc) is much higher for Ge than for Si.

IS is perhaps the key to Ge leakiness. "saturation current" is actually the current which flows in a junction with no voltage pushing it, just thermal agitation. I'd have to root for clues, but I suspect 1 femto Amp is orders of magnitude too low for Ge.

RB is often rubber-stamped as 10. I bet for older Ge it may be closer to 100-200 and this may be part of the higher voltage actual versus physical theory.

> The AC output is 120 mV p-p for a 1 mV p-p input (gain of 120, when Bf=50).  Huh?

Current gain is _NOT_ voltage gain ! ! !

For a zero impedance (simple simulated) driver, for voltage gain you have 100K/rE, where rE is the internal emitter impedance. For Si this is 27 ohms at 1mA; IIRC this has a factor of 2 which Ge lacks(?). You are working near 0.05mA, Si rE would be 540 ohms, voltage gain would be 185.

This is true for ANY hFE. BUT source impedance must be zero. If the hFE is 100, input impedance is like 54K which may work with gitar. If hFE were unity, the input impedance is 540 ohms, and no guitar will drive it well (but a simulator will, and not even complain).
  • SUPPORTER

flo

Sorry to bump this older topic, but I tried the AC128 SPICE model from "brett" (2 posts up), using 5Spice, but in a Fuzz Face simulation it does not bias correctly:
Collector of Q1 is around 8.3V and the Collector of Q2 is around 0V in the transient analysis.

Does anyone have a correct AC128 SPICE model that actually works in a Fuzz Face simulation?
Or has someone verified that the model is correct, which means I am doing something wrong?

Thanks for your input!

CynicalMan

I've found one that seems to works fine. I'm on my phone now but I can post it soon.


flo

#10
Thanks for that link.
I've also found and tried that AC128 model, but still my Fuzz Face 5Spice model does not bias correctly at all in 5Spice.
Did anyone try that AC128 model in a Fuzz Face simulation and made it work?

I did found the following Fuzz Face LT-Spice model that I'm currently trying in LT-Spice:
http://www.electricchili.com/pedal-development/lt-spice-fuzz-face-model/
http://www.electricchili.com/wp-content/uploads/2010/06/FuzzFace.asc
It seems to work at first sight but:
- the transistor model is a 2N5771 which is nothing like a AC128 transistor.
- the base of Q1 sets at -0,6V DC which is typical for silicium but not for a germanium transistor.
- even with the Gain set low, it distorts the input signal a lot.
So it does not really look good to me. :(

flo

#11
I have just substituted that "diyaudio" AC128 SPICE model for the 2N5571, into the LT-Spice Fuzz Face from "electricchili" and it biases correctly now: :)
Base Q1 = -0.2V DC.
Base Q2, Collector Q1 = -0.74V DC.
Collector Q2 = -4.6V DC.
Emitter Q2 = -0.51V DC.

Seems that 5Spice was just not up to it, or I made a mistake in my Fuzz Face model.
LT-Spice looks like a good SPICE simulation program and I wanted to start using it for a while anyway, so it's ok to leave 5Spice behind...

But the signal still completely distorts even with the "Gain" at minimum and the input sin signal at 10mV amplitude, which is a realistic average guitar signal strength imo.
With an input signal set at 2mV amplitude, the visible distortion is gone, so it seems to work on smaller signals than I thought.
Around 3mV input amplitude, at minimum Gain, Q1 collector starts to distort only the bottom side of the signal.

With max Gain, at 2mV input amplitude, Q1 Collector distorts only the bottom side of the signal but a lot more. Q2 Collector now shows both signal sides distorted.
At max Gain, Q2 Collector starts distorting second signal side at around 1.3mV input signal amplitude.

Well, it seems to be working so I'll try this Fuzz Face LT-Spice model with the "diyaudio" AC128 SPICE model some more.

@CynicalMan: Thanks for your help!
And thanks to the people that created LT-Spice! :)

pwediystmpbxr

#12
(Modified since first post and replies ... )
I have been experimenting with a Germanium Transistor Spice Model:

SPICE Model:
.MODEL GEPNP PNP(IS=1U BF=100 VAF=25 CJC=10P CJE=5P VJC=0.2 VJE=0.2 TF=10N TR=100N EG=0.67)

PSPICE Model (requires the + sign for each line break):

.MODEL GEPNP PNP(IS=1U BF=100 VAF=25
+ CJC=10P CJE=5P VJC=0.2 VJE=0.2
+ TF=10N TR=100N EG=0.67)
.END

Simple Formula for TF and TR Transit Time Calculation: 1/(2*Pi*fT)
where: Pi = approximately 3.14 and fT = High Frequency Limit

This is a very basic SPICE Model Filename: GEPNP.MOD
It can be renamed to whatever Transistor desired.
Some most commonly used are: AC128, NKT275, OC71, ASX12D ...

NOTE: eCAD SPICE Simulation 'Run' of Fuzz Face or similar Circuitry with Germanium Transistors provides more stable results with a 1000 Meg Ohm resistor from Collector to Base if there is no actual biasing resistance employed. The resistor is not required for the actual physical build.

I utilize TINA "The Complete Electronics Lab" (Versions 10 and 11 BasicPlus) Commercial Software.
50 years experience: Musical/Audio Electronics Inventor/Commercial VST-VSTi Designer/eCAD SPICE Modeler/Original Music Composer (Musical Notated Works)/Live Performance Musician/Recording Artist ... etc. All Owned Licensed Commercial Software Utilized.

PRR

#13
> Vbe of approximately 300-350mV (Typical of a Small Signal Germanium Transistor).

Most Ge, working at small-audio current, show Vbe nearer 150mV, sometimes less.

*AC127 PNP Germanium Transistor Spice Model
*alternate: NF=0.5 Is=10EE-8
.MODEL AC127_XP PNP (
IS=10u
NF=1
NR=1
ISE=0.5u
ISC=1u
NC=1.5
NE=1.5
BF=90
BR=5
VAF=40
VAR=40
RB=100
Rc=10
EG=0.67
CJC=10p
CJE=8p
VJC=0.25
VJE=0.25 )
*$


This shows Vbe of 80mV @ 0.2mA, 180mV @ 8mA, which is in-line with what I remember of the bad old days.

This model shows 0.117mA of current with 3V Vce and base "open" (1000Meg dummy resistor to emitter to foil SPICE complaint about unused pins), which is broadly reasonable for small vintage Ge devices. I do not know what parameter(s) make this happen.

The "unbiased" emitter current rises 10X for every 20 deg C of temperature rise. I am not sure this is right, but at least a temp-sweep will tell you if things go blooey much too easily.

This IS is significantly different from yours and goes to the root of Vbe. The other different and extra parameters, maybe not so much.

Obviously PSpice syntax is different from TINA.

We do now have a section for SPICE topics but it is well hidden.

  • SUPPORTER

PRR

> a 1 Meg Ohm resistor from Collector to Base if there is no actual biasing resistance employed.

No base feed resistor is just a Bad Idea. Yet it was often done, and a robust model should do something reasonable.

Here's the model above with 'open' base, and Rc selected(!) for about midway bias at some moderate temperature. At 20-21 deg C, yes it does bias-up just about center! But for this choice of values (parameters and resistor), by 25 deg C the maximum output is way down, while past 27 deg C it is just slammed and making half-waves at best. Past that it only farts-out the loud strums. The cold-side looks better; at 10C (50F) it is doing better than my fingers would. So we might select a smaller Rc to favor warmer temperatures. But clearly it can't (with bad bias) do New Years outside in NYC *and* 4 July in Arizona sunlight.

Plenty of ways to stabilize transistors, even crummy Ge parts. You come then to such as the BBC OBC preamps which had lovely stable clean sound in the worst weather, frostbite or heatstroke. But they were too elaborate for mere stompboxes.

  • SUPPORTER

Gert

Hello all,

Last year, I dedicated some of my spare time to a long pending project: the development of reliable SPICE models for several once widely-used germanium bipolar transistors. Besides my personal interest in this 'historical' subject, this work was also inspired by the obvious demand for such simulation models, for example, in this forum as well as in several other places:

http://www.guitarscience.net/index.htm
https://www.electrosmash.com/fuzz-face
https://www.diyaudio.com/forums/solid-state/117257-ac128-pnp-germanium-transistor-spice-model-rare.html

In fact, it was Jarmo Lähdevaara's fascinating book The Science of Electric Guitars and Guitar Electronics (first link above) which had brought this topic back onto my agenda...

Initially, I had tried to follow a more formal strategy similar to that described in Jarmo's book, with some, yet somewhat limited success. Therefore, I finally gave up these theoretical attempts and decided to go back to the roots, so to say, of this whole problem and perform a global optimization on all relevant model parameters using the entire datasheets as references for the respective objective functions.

For this, I took the Valvo and Mullard datasheets, digitized all relevant curves, added a couple of explicitly given characteristics, and put everything into a giant optimization. I used the squared relative deviations from all characteristics (one value per characteristic) plus the mean squared deviations from all digitized curves (one accumulated value per curve) as error function elements—and then let the MacSpice optimizer do most of the job.

I have been using MacSpice for years for such demanding research purposes because this free-ware tool combines a higher-level programming language (the MacSpice front-end) with an enhanced, highly reliable SPICE 3f5 circuit simulator, plus numerous useful built-in functions (see http://www.macspice.com). Without such a powerful research tool, this whole project would have been impossible, or at least much harder, to do for me. One minor caveat particularly for novice users, however, might be that programming skills are indispensable for using MacSpice in this way most effectively.

Owing to the complexity of the above objective functions, roughly 300 lines of code were needed merely for the function evaluations, plus another 600–800 lines for controlling the corresponding optimizations. For the AC128, for example, each evaluation involved

– 53 OP analyses (2×25 for operating-point iterations)
– 15 AC sweeps for various frequency characteristics
– 8   DC sweeps for static curve characteristics
– 1   DC TEMP sweep for the leakage-current characteristics

and required roughly one second of CPU time on my older Mac—for each one of the hundreds of thousands function calls needed to reach my final results!

Everyone who has ever attempted such a complex, non-linear optimization of a function of so many variables might have observed that such optimizations often tend to converge merely to some local optima instead of the 'true' global optimum. To overcome this as far as possible, I picked ten randomized starting points in the vicinity of my initial guess, performed the corresponding ten independent optimizations, and then took the averaged results from these optimizations as the new starting point for the next round. This basic procedure was repeated until no further (significant) improvement could be obtained.

A few weeks (!) of CPU time later, I finally had really good SPICE models for seven Valvo/Mullard germanium transistors at hand: for the AC125, AC126, AC127, AC128, AC132, OC44, and OC45. The two OC models were mainly developed for the simulation of one of the first high-quality RIAA phono pre-amplifiers, published in 1965 by J. Dinsdale (Wireless World, January 1965); see also http://www.douglas-self.com/ampins/discrete/2Q-RIAA/2Q-RIAA.htm.

And here are my finally obtained BJT models for the above five AC transistors:

*-------------------------------------------------
*  AC125 Spice model
*  Germanium PNP transistor in TO-1 metal case
*  Copyright (c) 2020 by Gert Willmann
*-------------------------------------------------
.model AC125 pnp (
+  is=25.1u
+  bf=122 nf=0.957 vaf=30 ikf=0.42 ise=0.3u ne=1.78
+  br=12.2 nr=0.957 var=30 ikr=0.42 isc=3.03u nc=2.07
+  rc=1.58 re=0.327 rb=93.4 rbm=13.5 irb=0.153m
+  cje=130p vje=0.3 mje=0.5
+  cjc=173p vjc=0.3 mjc=0.5
+  tf=86.2n tr=862n
+  eg=0.67 xti=8.27 xtb=1.5 fc=0.5
+  kf=4.25f af=1
+  tnom=25 )

*-------------------------------------------------
*  AC126 Spice model
*  Germanium PNP transistor in TO-1 metal case
*  Copyright (c) 2020 by Gert Willmann
*-------------------------------------------------
.model AC126 pnp (
+  is=25.7u
+  bf=178 nf=0.949 vaf=26 ikf=0.229 ise=0.3u ne=1.78
+  br=17.8 nr=0.949 var=26 ikr=0.229 isc=3.51u nc=1.8
+  rc=1.34 re=0.382 rb=91.2 rbm=19.1 irb=0.174m
+  cje=130p vje=0.3 mje=0.5
+  cjc=173p vjc=0.3 mjc=0.5
+  tf=62.8n tr=628n
+  eg=0.67 xti=9.93 xtb=1.5 fc=0.5
+  kf=4.9f af=1
+  tnom=25 )

*-------------------------------------------------
*  AC127/AC127K Spice model
*  Germanium NPN transistor in TO-1 metal case
*  Copyright (c) 2020 by Gert Willmann
*-------------------------------------------------
.model AC127 npn (
+  is=10.4u
+  bf=165 nf=0.875 vaf=50 ikf=0.383 ise=0.252u ne=1.22
+  br=16.5 nr=0.875 var=50 ikr=0.383 isc=5.58u nc=1.79
+  rc=0.94 re=0.271 rb=70.4 rbm=14.4 irb=1.33m
+  cje=220p vje=0.3 mje=0.5
+  cjc=294p vjc=0.3 mjc=0.5
+  tf=65.5n tr=655n
+  eg=0.67 xti=13.9 xtb=1.5 fc=0.5
+  kf=3.5f af=1
+  tnom=25 )

*-------------------------------------------------
*  AC128/AC128K Spice model
*  Germanium PNP transistor in TO-1 metal case
*  Copyright (c) 2020 by Gert Willmann
*-------------------------------------------------
.model AC128 pnp (
+  is=29.4u
+  bf=146 nf=1.095 vaf=39 ikf=5.7 ise=0.356u ne=1.29
+  br=14.6 nr=1.095 var=39 ikr=5.7 isc=1.38u nc=2.8
+  rc=0.299 re=0.061 rb=25.1 rbm=2.67 irb=2.37m
+  cje=315p vje=0.3 mje=0.5
+  cjc=420p vjc=0.3 mjc=0.5
+  tf=108n tr=1080n
+  eg=0.67 xti=5.08 xtb=1.5 fc=0.5
+  kf=5.7f af=1
+  tnom=25 )

*-------------------------------------------------
*  AC132 Spice model
*  Germanium PNP transistor in TO-1 metal case
*  Copyright (c) 2020 by Gert Willmann
*-------------------------------------------------
.model AC132 pnp (
+  is=34.9u
+  bf=154 nf=1.036 vaf=30 ikf=0.171 ise=0.595u ne=2.48
+  br=15.4 nr=1.036 var=30 ikr=0.171 isc=2.5u nc=1.74
+  rc=0.546 re=0.311 rb=90.8 rbm=10.9 irb=0.649m
+  cje=126p vje=0.3 mje=0.5
+  cjc=168p vjc=0.3 mjc=0.5
+  tf=72.7n tr=727n
+  eg=0.67 xti=7.26 xtb=1.5 fc=0.5
+  kf=4.7f af=1
+  tnom=25 )

The two OC models are a little bit simpler:

*-------------------------------------------------
*  OC44 Spice model
*  Germanium PNP transistor in all-glass case
*  Copyright (c) 2020 by Gert Willmann
*-------------------------------------------------
.model OC44 pnp (
+  is=2.54u
+  bf=111 nf=0.977 vaf=11.5 ise=56.9n ne=1.23
+  br=11.1 nr=0.977 var=11.5 isc=194n nc=2.21
+  rc=1.45 re=0.504 rb=109
+  cje=28.2p vje=0.3 mje=0.5
+  cjc=47p vjc=0.3 mjc=0.5
+  tf=8.69n tr=86.9n
+  eg=0.67 xti=8.26 xtb=1.5 fc=0.5
+  kf=27f af=1
+  tnom=25 )

*-------------------------------------------------
*  OC45 Spice model
*  Germanium PNP transistor in all-glass case
*  Copyright (c) 2020 by Gert Willmann
*-------------------------------------------------
.model OC45 pnp (
+  is=1.23u
+  bf=76 nf=1.066 vaf=21 ise=62.6n ne=1.3
+  br=7.6 nr=1.066 var=21 isc=268n nc=1.33
+  rc=0.246 re=1.19 rb=75.8
+  cje=28.3p vje=0.3 mje=0.5
+  cjc=47.2p vjc=0.3 mjc=0.5
+  tf=25.7n tr=257n
+  eg=0.67 xti=7.07 xtb=1.5 fc=0.5
+  kf=15.5f af=1
+  tnom=25 )

Due to the lack of available data for the reverse mode of operation (which is of little practical importance anyway) and several other characteristics, I used the following simplifying, yet not quite unrealistic assumptions:

BR = BF/10        (from measurements made by Benjamin Holmes)
NR = NF           (a reasonable assumption)
VAR = VAF         (VAR may even be somewhat higher, according to Benjamin Holmes)
IKR = IKF         (an estimate which is better than the default value infinity)
CJE = 0.75*CJC    (for the AC models, borrowed from ASY76/77/80 datasheets)
CJE = 0.60*CJC    (for the OC models, borrowed from ASY26/27 datasheets)
VJE = VJC = 0.3   (0.25–0.35 are typical values for low-power germanium BJTs)
MJE = MJC = 0.5   (typical value for abrupt, alloy junctions)
TR = 10*TF        (a reasonable first-order estimate)
EG = 0.67         (the default value for germanium)
XTB = 1.5         (extracted from some other germanium BJT datasheets)
FC = 0.5          (SPICE default)
AF = 1            (SPICE default)

Note that 'TNOM', the parameter measurement temperature, is 25°C according to the datasheets instead of the SPICE default of 27°C; this can make a non-negligible difference for such leaky germanium transistors. Unfortunately, as far as I know, these genuine SPICE models may not be correctly understood by some other simulators. For instance, 'TNOM' is called 'T_MEASURED' in PSpice and 'TREF' in HSpice.

Three example plots for the above AC128 model (emitter current vs. base-emitter voltage, collector-base leakage current vs. temperature) are attached just for your information. Note, however, that any verification of the above models requires that the respective operating conditions are reproduced precisely as specified in the datasheets. With this, all seven models ought to reflect the relevant datasheet characteristics very well—and much better than any other models I've found elsewhere!

Finally, as regards the relatively high base-emitter and base-collector depletion capacitances (model parameters 'CJE' and 'CJC') particularly of the AC transistors, it is important to note that these are highly non-linear, voltage-dependent capacitances which can have a significant impact on the transient behavior at higher audio frequencies. This may be of particular interest in connection with effect devices based on such transistors.






Rob Strand

#16
QuoteLast year, I dedicated some of my spare time to a long pending project: the development of reliable SPICE models for several once widely-used germanium bipolar transistors. Besides my personal interest in this 'historical' subject, this work was also inspired by the obvious demand for such simulation models, for example, in this forum as well as in several other places:

You have a done a really great job.   The best effort I've seen coming up with a good set of models.    I liked your whole approach.   It should produce some very reasonable results.  Good models for germanium transistors is something which has been missing for years.   So your efforts are much appreciated.

I put a lot of stuff through optimizers so I get what you have done here.  For some problems I'll use 500 or more random start points with large deviations then take that result and do another 500 with more smaller deviations.  It does make a difference.  Totally impractical unless you are running native code like compiled C.

The only thing I could add is to have high and low leakage versions of the models.  The leakage can vary widely even for the same part number.   It's something that needs to be set more than extracted from the datasheet.   In the past I created some ge models like this.  What isn't clear is the best way to do it.  Changing the IS is a simple way but it affects both junctions.  It also changes the VBE which may be valid to some degree but I always thought a separate leakage current, outside of the model, might represent surface leakage better.   It's something which is hard to find physically realistic models for.
Send:     . .- .-. - .... / - --- / --. --- .-. -

PRR

Yes; a stunningly useful contribution.

Quote from: Gert on February 01, 2021, 09:01:10 AM
.....
Due to the lack of available data for the reverse mode of operation (which is of little practical importance anyway)
BR = BF/10        (from measurements made by Benjamin Holmes)....

FWIW: in many of the oldest transistors, making a junction was so awkward, that both junctions were essentially the same. A clue is that the emitter breakdown voltage is same-as the collector. Later they had ways to process differently, and ended up near 7V emitter breakdown for bets gain. I would assume that in a Symmetrical device BR==BF within process tolerance.

Some of these type-numbers ran for many-many years and may have been made both ways.

And as you say it rarely matters. We used this fact in switches and a few stranger things best forgotten.
  • SUPPORTER

Rob Strand

#18
QuoteAnd as you say it rarely matters. We used this fact in switches and a few stranger things best forgotten.
It's nice to have a model with a reasonable BR.  If you run it in reverse at least is behaves half OK.   There's plenty of models for common silicon transistor from large manufactures with very dismal reverse modelling.   I've seen eyebrow raising weird results from saturating BJTs - terrible!

I can't say I've verified the BR = BF/10 for germaniums  but it looks reasonable.   I'd be happy to use it mainly because the narrow range of gains for ge devices ends-up with a reasonable BR value.   Most BR's end-up between say 1 and 10.     

For silicon's I have seen some correlation between BR and  BF but I'm still slightly reluctant to assign a BR which is a scaling of BF.  You might be safer just to assign a value of 4.0, at least for collector currents around 100uA to 1mA.   A confounding factor is BR can be a fairly strong function of collector current.    It would be nice to get a reverse beta measurement for BJT with a gain of 800 to 1000.   As weak evidence, take this 2N5088 model from Fairchild (who's models are OK),

NPN (Is=5.911f Xti=3 Eg=1.11 Vaf=62.37 Bf=1.122K Ne=1.394 Ise=5.911f Ikf=14.92m Xtb=1.5 Br=1.271 Nc=2
Isc=0 Ikr=0 Rc=1.61 Cjc=4.017p Mjc=.3174 Vjc=.75 Fc=.5 Cje=4.973p Mje=.4146 Vje=.75 Tr=4.673n Tf=821.7p
Itf=.35 Vtf=4 Xtf=7 Rb=10)

This model has BF=1122 and BR = 1.271

You see BR = 1.2 or so in 2N3904's which have BF's of 120 or so.   So the deriving BF from BR by scaling would have a 1:10 error as the scale factor can only be correct for one or the other.


Send:     . .- .-. - .... / - --- / --. --- .-. -

Rob Strand

#19
I've got a Fairchild PN4355 (PNP Silicon transistor) in my junk tray.   It measured BR = 104 and BR=9.7.
So,

2N5088 spice model          BF/BR  = 882,    BR = 1.3
PN4355 measurement       BF/BR  = 10.7,   BR = 9.7
2N3904 measurement        BF/BR  = 65,      BR = 1.6

The BF/BR ratio varies by a factor of 100 (approx).  Whereas assuming a range of BR from 1 to 10 we only vary by a factor 10.
So assigning a value of BR = 4 has a lot less error, which was the point I made earlier.

Not the mention the current dependency.  For the 2N3904 the BR drops to the 0.25 to 0.5 region at low currents.

Keep in mind these results are for silicon transistors.

In the past I have seen correlation between BF and BR.  Where using a ratio of BF vs BR might be useful (not verified) is when you have the same transistor part number with different forward gains (BF).    As shown above the correlation doesn't work across different parts.   Where it might be possible to extend the correlation to different parts is if the transistors are made under the same process.  If you look at the older National semiconductor and Fairchild documents and datasheets you will see different transistors part numbers are made  under the same process.
Send:     . .- .-. - .... / - --- / --. --- .-. -